[windows] Windows 명령 행에서 배치 파일에서 매개 변수 사용

@ Jon ‘s :parse/:endparse scheme은 훌륭한 출발이며, 그는 초기 패스에 대해 감사를 표하지만 Windows 고문 배치 시스템을 사용하면 쉽게 해결할 수 있다고 생각한다면 … 내 친구, 당신은 충격을 받고 있습니다. 나는 하루 종일이 악마와 함께 보냈고, 많은 고통스러운 연구와 실험 끝에 마침내 실용 유틸리티를 위해 실행 가능한 것을 관리했습니다.

유틸리티를 구현하고 싶다고하자 foobar. 초기 명령이 필요합니다. 여기에는 선택적 값 --foo을 갖는 선택적 매개 변수 가 있습니다 (물론 다른 매개 변수 일 수는 없음). 값이 없으면 기본값은 입니다. 또한 필요한 값 을 취하는 선택적 매개 변수 가 있습니다. 마지막으로 값이 허용되지 않은 플래그 를 사용할 수 있습니다. 아, 그리고 이러한 매개 변수는 어떤 순서로든 올 수 있습니다.default--bar--baz

다시 말해, 다음과 같이 보입니다 :

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

복잡한? 아니, 그것은 실제 유틸리티의 전형적인 것 같습니다. ( git누구?)

더 이상 고민하지 않으면 여기에 해결책이 있습니다.

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

예, 정말 나쁩니다. https://stackoverflow.com/a/50653047/421049 에서 비슷한 게시물을 참조하십시오. . 여기서 논리에서 진행중인 작업과 특정 구문을 사용한 이유에 대한 자세한 분석을 제공합니다.

끔찍한. 그 중 대부분은 오늘 배워야했습니다. 그리고 그것은 아프다.

답변