더 많은 문제

@Lectrode에서 지적한 것처럼 net session서버 서비스가 중지 된 상태에서 명령 을 실행하려고 하면 다음 오류 메시지가 나타납니다.

The Server service is not started.

More help is available by typing NET HELPMSG 2114

이 경우 %errorLevel%변수는로 설정됩니다 2.

참고 안전 모드 (네트워킹 유무에 관계없이)에는 서버 서비스가 시작되지 않습니다.

대안을 찾고

무언가:

• Windows XP 이상 (32 비트 및 64 비트)에서 즉시 사용할 수 있습니다.
• 레지스트리 나 시스템 파일 / 폴더를 건드리지 않습니다.
• 시스템 로케일에 관계없이 작동합니다.
• 안전 모드에서도 정확한 결과를 제공합니다.

그래서 나는 바닐라 Windows XP 가상 머신을 부팅하고 C:\Windows\System32폴더 의 응용 프로그램 목록을 스크롤하면서 몇 가지 아이디어를 얻었습니다. 시행 착오 후에, 이것은 내가 생각해 낸 더러운 (pun 의도 된) 접근법입니다.

fsutil dirty query %systemdrive% >nul

이 fsutil dirty명령을 실행하려면 관리자 권한이 필요하며 그렇지 않으면 실패합니다. 운영 체제가 설치된 드라이브 문자를 반환 %systemdrive%하는 환경 변수 입니다. 출력이로 리디렉션 nul되어 무시됩니다. %errorlevel%변수에 설정됩니다 0만 성공적으로 실행시.

다음은 설명서의 내용입니다.

더러운 Fsutil

볼륨의 더티 비트를 쿼리하거나 설정합니다. 볼륨의 더티 비트가 설정되면 autochk 는 다음에 컴퓨터를 다시 시작할 때 볼륨에 오류가 있는지 자동으로 확인합니다.

통사론

fsutil dirty {query | set} <VolumePath>

매개 변수

query           Queries the specified volume's dirty bit.
set             Sets the specified volume's dirty bit.
<VolumePath>    Specifies the drive name followed by a colon or GUID.

비고

볼륨의 더티 비트는 파일 시스템이 일관성이없는 상태임을 나타냅니다. 더티 비트는 다음과 같은 이유로 설정 될 수 있습니다.

• 볼륨이 온라인 상태이며 크게 변경되었습니다.
• 변경 사항이 디스크에 적용되기 전에 볼륨이 변경되고 컴퓨터가 종료되었습니다.
• 볼륨에서 손상이 발견되었습니다.

컴퓨터가 다시 시작될 때 더티 비트가 설정되면 chkdsk 가 실행되어 파일 시스템 무결성을 확인하고 볼륨 관련 문제를 해결하려고 시도합니다.

예

C 드라이브에서 더티 비트를 쿼리하려면 다음을 입력하십시오.

fsutil dirty query C:

추가 연구

위의 솔루션은 Windows XP부터 작동하지만 Windows 2000 및 Windows PE (사전 설치 환경)에는 포함되지 않는 추가 가치가 있습니다. fsutil.exe 합니다.

이전 테스트 중에 sfc매개 변수없이 명령 을 실행하면 다음과 같은 결과가 나타납니다.

• 권한이 충분하지 않은 경우 오류;
• 사용 가능한 매개 변수 및 사용법 목록.

즉 : 매개 변수가 없고 파티가 없습니다 . 아이디어는 출력을 구문 분석하고 오류 이외의 것이 있는지 확인할 수 있다는 것입니다.

sfc 2>&1 | find /i "/SCANNOW" >nul

오류 출력은 먼저 표준 출력으로 리디렉션 된 다음 find명령으로 파이프됩니다 . 이 시점 에서 Windows 2000 이후의 모든 Windows 버전에서 지원되는 유일한 매개 변수 를 찾아야합니다 . 검색은 대소 문자를 구분하지 않으며로 리디렉션하여 출력을 버립니다 ./SCANNOWnul

다음은 설명서에서 발췌 한 내용입니다.

Sfc

보호 된 모든 시스템 파일의 무결성을 검사하고 확인하고 잘못된 버전을 올바른 버전으로 바꿉니다.

비고

sfc.exe 를 실행하려면 Administrators 그룹의 구성원으로 로그온해야합니다 .

샘플 사용법

붙여 넣기 및 실행 예제는 다음과 같습니다.

Windows XP 이상

@echo off

call :isAdmin
if %errorlevel% == 0 (
echo Running with admin rights.
) else (
echo Error: Access denied.
)

pause >nul
exit /b

:isAdmin
fsutil dirty query %systemdrive% >nul
exit /b

Windows 2000 / Windows PE

@echo off

call :isAdmin
if %errorlevel% == 0 (
echo Running with admin rights.
) else (
echo Error: Access denied.
)

pause >nul
exit /b

:isAdmin
sfc 2>&1 | find /i "/SCANNOW" >nul
exit /b

적용

• 윈도우 2000
• 윈도우 XP
• 윈도우 비스타
• 윈도우 7
• 윈도우 8
• 윈도우 8.1
  
  —
• Windows PE

답변

fltmc >nul 2>&1 && (
  echo has admin permissions
) || (
  echo has NOT admin permissions
)

setlocal enableDelayedExpansion
set "dv==::"
if defined !dv! (
   echo has NOT admin permissions
) else (
   echo has admin permissions
)

set ^"|find "::"||echo has admin permissions

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"&&(
 echo admin...
)

@echo off
pushd %SystemRoot%
openfiles.exe 1>nul 2>&1
if not %errorlevel% equ 0 (
    Echo here you are not administrator!
) else (
    Echo here you are administrator!
)
popd
Pause

@echo off
REM Quick test for Windows generation: UAC aware or not ; all OS before NT4 ignored for simplicity
SET NewOSWith_UAC=YES
VER | FINDSTR /IL "5." > NUL
IF %ERRORLEVEL% == 0 SET NewOSWith_UAC=NO
VER | FINDSTR /IL "4." > NUL
IF %ERRORLEVEL% == 0 SET NewOSWith_UAC=NO


REM Test if Admin
CALL NET SESSION >nul 2>&1
IF NOT %ERRORLEVEL% == 0 (

    if /i "%NewOSWith_UAC%"=="YES" (
        rem Start batch again with UAC
        echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
        echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
        "%temp%\getadmin.vbs"
        del "%temp%\getadmin.vbs"
        exit /B
    )

    rem Program will now start again automatically with admin rights!
    rem pause
    goto :eof
)