요약해서 말하자면

이를 수행하는 몇 가지 방법이 있으며 그 중 대부분이 제안되었지만 두 가지 추가 방법으로 요약 할 것이라고 생각했습니다.

• vimrc에 디렉토리 당 – 빔이 올바른 디렉토리에서 시작해야한다는 단점이있다 : 프로젝트가있는 경우 ~/project1와, 당신은 ~/project1/.vim.custom하고 할cd ~ ; vim project1/file.c 사용자 지정 설정을 찾을 수 없습니다.
• Modelines-매우 효과적이지만 모든 파일에 추가해야한다는 단점이 있습니다 (새 파일에 추가해야 함).
• 디렉토리 특정 자동 명령-이것은 매우 효과적입니다.
• 파일에서 특정 헤더를 스캔합니다 (아래 참조)-이것은 과거에 다른 회사에서 일하거나 명확하게 이름이 지정된 프로젝트에서 가장 많이 사용했던 헤더입니다.
• 파일이 열릴 때 확인되는 디렉토리 별 vimrc입니다 (아래 참조). 특히 프로젝트 코드가 모두 한 곳에있는 경우 구현하기 매우 쉬운 또 다른 방법입니다.

헤더 스캔

많은 조직에서 모든 소스 파일의 맨 위에 표준 헤더 (저작권 고지 및 프로젝트 이름 등)가 있습니다. 이 경우 Vim이 파일의 첫 10 줄을 자동으로 스캔하여 키워드를 찾을 수 있습니다. 찾으면 설정을 변경할 수 있습니다. 내가 사용하는 양식 (다른 많은 작업을 수행함)보다 더 간단하게 만들도록 수정했지만 ~/.vim/after/filetype.vim아직없는 경우 다음과 같이 추가합니다.

au FileType * call <SID>ConfigureFiletypes(expand("<amatch>"))

" List of file types to customise
let s:GROUPNAMETypes = ['c', 'cpp', 'vhdl', 'c.doxygen']

func! <SID>CheckForGROUPNAMECode()
    " Check if any of the first ten lines contain "GROUPNAME".

    " Read the first ten lines into a variable
    let header = getline(1)
    for i in range(2, 10)
        let header = header . getline(i)
    endfor

    if header =~ '\<GROUPNAME\>'
        " Change the status line to make it clear which
        " group we're using
        setlocal statusline=%<%f\ (GROUPNAME)\ %h%m%r%=%-14.(%l,%c%V%)\ %P
        " Do other customisation here
        setlocal et
        " etc
    endif
endfunc

func! <SID>ConfigureFiletypes(filetype)
    if index(s:GROUPNAMETypes, a:filetype) != -1
        call <SID>CheckForGROUPNAMECode()
    endif
endfunc

모든 유형의 파일이 열리고 파일 유형이 설정 ( au FileType *행) 될 때마다ConfigureFiletypes 함수가 호출됩니다. 파일 형식이 현재 그룹 (GROUPNAME)과 연결된 파일 형식 목록에 있는지 확인합니다 (이 경우 ‘c’, ‘cpp’, ‘vhdl’또는 ‘c.doxygen’). 그렇다면 CheckForGROUPNAMECode ()를 호출하여 파일의 처음 10 줄을 읽고 GROUPNAME을 포함하면 일부 사용자 지정을 수행합니다. 확장 탭 등을 설정하는 것 외에도 그룹 이름이 명확하게 표시되도록 상태 표시 줄이 변경되어 한 눈에 작동하는지 알 수 있습니다.

열 때 구성 확인

JS Bangs의 제안과 마찬가지로 사용자 정의 구성 파일을 갖는 것이 유용 할 수 있습니다. 그러나 vimrc에서로드하는 대신 .c 파일과 동일한 디렉토리에있는 .vim.custom에 대해 .c 파일이 열릴 때 확인하는 다음과 같은 것을 고려하십시오.

au BufNewFile,BufRead *.c call CheckForCustomConfiguration()

function! CheckForCustomConfiguration()
    " Check for .vim.custom in the directory containing the newly opened file
    let custom_config_file = expand('%:p:h') . '/.vim.custom'
    if filereadable(custom_config_file)
        exe 'source' custom_config_file
    endif
endfunction