다음 모듈을 사용하여 Microsoft가 제안한 해결 방법 (테이블 대신 쿼리 사용)을 자동으로 구현하십시오. 예방책으로 먼저 데이터베이스를 백업하십시오.

AddWorkaroundForCorruptedQueryIssue()임시 해결책을 추가하고 RemoveWorkaroundForCorruptedQueryIssue()언제든지 제거하는 데 사용하십시오 .

Option Compare Database
Option Explicit

Private Const WorkaroundTableSuffix As String = "_Table"

Public Sub AddWorkaroundForCorruptedQueryIssue()
    On Error Resume Next

    With CurrentDb
        Dim tableDef As tableDef
        For Each tableDef In .tableDefs
            Dim isSystemTable As Boolean
            isSystemTable = tableDef.Attributes And dbSystemObject

            If Not EndsWith(tableDef.Name, WorkaroundTableSuffix) And Not isSystemTable Then
                Dim originalTableName As String
                originalTableName = tableDef.Name

                tableDef.Name = tableDef.Name & WorkaroundTableSuffix

                Call .CreateQueryDef(originalTableName, "select * from [" & tableDef.Name & "]")

                Debug.Print "OldTableName/NewQueryName" & vbTab & "[" & originalTableName & "]" & vbTab & _
                            "NewTableName" & vbTab & "[" & tableDef.Name & "]"
            End If
        Next
    End With
End Sub

Public Sub RemoveWorkaroundForCorruptedQueryIssue()
    On Error Resume Next

    With CurrentDb
        Dim tableDef As tableDef
        For Each tableDef In .tableDefs
            Dim isSystemTable As Boolean
            isSystemTable = tableDef.Attributes And dbSystemObject

            If EndsWith(tableDef.Name, WorkaroundTableSuffix) And Not isSystemTable Then
                Dim originalTableName As String
                originalTableName = Left(tableDef.Name, Len(tableDef.Name) - Len(WorkaroundTableSuffix))

                Dim workaroundTableName As String
                workaroundTableName = tableDef.Name

                Call .QueryDefs.Delete(originalTableName)
                tableDef.Name = originalTableName

                Debug.Print "OldTableName" & vbTab & "[" & workaroundTableName & "]" & vbTab & _
                            "NewTableName" & vbTab & "[" & tableDef.Name & "]" & vbTab & "(Query deleted)"
            End If
        Next
    End With
End Sub

'From https://excelrevisited.blogspot.com/2012/06/endswith.html
Private Function EndsWith(str As String, ending As String) As Boolean
     Dim endingLen As Integer
     endingLen = Len(ending)
     EndsWith = (Right(Trim(UCase(str)), endingLen) = UCase(ending))
End Function

내 GitHub 리포지토리 에서 최신 코드를 찾을 수 있습니다 .

AddWorkaroundForCorruptedQueryIssue()_Table모든 비 시스템 테이블에 접미사 를 추가합니다 . 예를 들어 테이블의 IceCreams이름이IceCreams_Table .

또한 원래 테이블 이름을 사용하여 새 쿼리를 작성하여 이름이 바뀐 테이블의 모든 열을 선택합니다. 이 예에서 쿼리 이름이 지정 IceCreams되고 SQL이 실행 select * from [IceCreams_Table]됩니다.

RemoveWorkaroundForCorruptedQueryIssue() 역 동작을 수행합니다.

SQL Server와 같은 외부 비 MDB 테이블을 포함하여 모든 종류의 테이블에서 이것을 테스트했습니다. 그러나 테이블 대신 쿼리를 사용하면 특히 테이블을 사용한 원래 쿼리의 품질이 떨어지거나 매우 복잡한 경우 특정 경우 백엔드 데이터베이스에 대해 최적화되지 않은 쿼리가 실행될 수 있습니다.

(물론 코딩 스타일에 따라 응용 프로그램에서 문제가 발생할 수도 있습니다. 따라서 수정 프로그램이 일반적으로 적합한 지 확인한 후에는 모든 개체를 텍스트로 내보내고 찾기 바꾸기를 사용하는 것은 결코 나쁜 생각이 아닙니다 사용되는 테이블 이름이 테이블이 아닌 쿼리에 대해 실행되도록하는 마술.)

필자의 경우이 수정은 부작용없이 크게 작동합니다 . 과거에 만들 때 시스템 테이블로 표시하지 않았기 때문에 수동으로 이름을 USysRibbons_Table다시 USysRibbons바꾸어야했습니다.

답변

msiexec /i {90160000-0011-0000-0000-0000000FF1CE} MSIPATCHREMOVE={9894BF35-19C1-4C89-A683-D40E94D08C77} /qn REBOOT=REALLYSUPPRESS

OfficeUpdateRemover.ps1 -kb 4484127