vim

다음 은 2 단계 접근 방식 ( :,$s/BEFORE/AFTER/gc|1,''-&&) 또는 중간 “파일 시작 부분에서 계속 하시겠습니까?”로 검색을 래핑하는 것에 대한 우려를 해결하는 매우 대략적인 내용입니다. 접근하다:

" Define a mapping that calls a command.
nnoremap <Leader>e :Substitute/\v<<C-R>=expand('<cword>')<CR>>//<Left>

" And that command calls a script-local function.
command! -nargs=1 Substitute call s:Substitute(<q-args>)

function! s:Substitute(patterns)
  if getregtype('s') != ''
    let l:register=getreg('s')
  endif
  normal! qs
  redir => l:replacements
  try
    execute ',$s' . a:patterns . 'gce#'
  catch /^Vim:Interrupt$/
    return
  finally
    normal! q
    let l:transcript=getreg('s')
    if exists('l:register')
      call setreg('s', l:register)
    endif
  endtry
  redir END
  if len(l:replacements) > 0
    " At least one instance of pattern was found.
    let l:last=strpart(l:transcript, len(l:transcript) - 1)
    " Note: type the literal <Esc> (^[) here with <C-v><Esc>:
    if l:last ==# 'l' || l:last ==# 'q' || l:last ==# '^['
      " User bailed.
      return
    endif
  endif

  " Loop around to top of file and continue.
  " Avoid unwanted "Backwards range given, OK to swap (y/n)?" messages.
  if line("''") > 1
    1,''-&&"
  endif
endfunction

이 함수는 몇 가지 해킹을 사용하여 맨 위로 돌아 가야하는지 확인합니다.

• 사용자가 “l”, “q”또는 “Esc”를 눌렀을 때 줄 바꿈을하지 않습니다.이 중 어느 것이 든 중단하려는 것을 나타냅니다.
• “s”레지스터에 매크로를 기록하고 마지막 문자를 검사하여 마지막 키 누름을 감지합니다.
• “s”레지스터를 저장 / 복원하여 기존 매크로를 덮어 쓰지 마십시오.
• 명령을 사용할 때 이미 매크로를 기록하고 있다면 모든 베팅이 해제됩니다.
• 인터럽트로 올바른 일을하려고합니다.
• 명시적인 가드로 “뒤로 범위”경고를 피합니다.

답변