[php] WAMPServer의 Windows 명령 줄에서 PHP를 실행하는 방법

그것은에 살고 php.exe가 (명령 줄 인터페이스에 대한 PHP)이라고 불리는 같은 PHP CLI가 호출됩니다 c:\wamp\bin\php\php5.x.y\php.exe (x와 y가 설치 한 것을 PHP의 버전 번호입니다)

명령 줄에서 실행할 PHP 스크립트를 만들고 싶다면 쉽고 매우 유용합니다.

이와 같은 배치 파일을 직접 만들고 다음과 같이 호출하십시오 phppath.cmd.

PATH=%PATH%;c:\wamp\bin\php\phpx.y.z
php -v

x.y.zWAMPServer에 설치 한 PHP 버전의 유효한 폴더 이름으로 변경하십시오.

이미 PATH에있는 폴더 중 하나에 저장하여 어디서나 실행할 수 있습니다.

이제 명령 창에서 소스 폴더로 cd하고> phppath를 실행합니다.

그런 다음 실행

php your_script.php

꿈처럼 작동해야합니다.

다음은 필요한 경우 PHP Composer 및 PEAR를 구성하는 예입니다.

@echo off

REM **************************************************************
REM * PLACE This file in a folder that is already on your PATH
REM * Or just put it in your C:\Windows folder as that is on the
REM * Search path by default
REM * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
REM * EDIT THE NEXT 3 Parameters to fit your installed WAMPServer
REM **************************************************************


set baseWamp=D:\wamp
set defaultPHPver=7.4.3
set composerInstalled=%baseWamp%\composer
set phpFolder=\bin\php\php

if %1.==. (
    set phpver=%baseWamp%%phpFolder%%defaultPHPver%
) else (
    set phpver=%baseWamp%%phpFolder%%1
)

PATH=%PATH%;%phpver%
php -v
echo ---------------------------------------------------------------


REM IF PEAR IS INSTALLED IN THIS VERSION OF PHP

IF exist %phpver%\pear (
    set PHP_PEAR_SYSCONF_DIR=D:\wamp\bin\php\php%phpver%
    set PHP_PEAR_INSTALL_DIR=D:\wamp\bin\php\php%phpver%\pear
    set PHP_PEAR_DOC_DIR=D:\wamp\bin\php\php%phpver%\docs
    set PHP_PEAR_BIN_DIR=D:\wamp\bin\php\php%phpver%
    set PHP_PEAR_DATA_DIR=D:\wamp\bin\php\php%phpver%\data
    set PHP_PEAR_PHP_BIN=D:\wamp\bin\php\php%phpver%\php.exe
    set PHP_PEAR_TEST_DIR=D:\wamp\bin\php\php%phpver%\tests

    echo PEAR INCLUDED IN THIS CONFIG
    echo ---------------------------------------------------------------
) else (
    echo PEAR DOES NOT EXIST IN THIS VERSION OF php
    echo ---------------------------------------------------------------
)

REM IF A GLOBAL COMPOSER EXISTS ADD THAT TOO
REM **************************************************************
REM * IF A GLOBAL COMPOSER EXISTS ADD THAT TOO
REM *
REM * This assumes that composer is installed in /wamp/composer
REM *
REM **************************************************************
IF EXIST %composerInstalled% (
    ECHO COMPOSER INCLUDED IN THIS CONFIG
    echo ---------------------------------------------------------------
    set COMPOSER_HOME=%baseWamp%\composer
    set COMPOSER_CACHE_DIR=%baseWamp%\composer

    PATH=%PATH%;%baseWamp%\composer

    rem echo TO UPDATE COMPOSER do > composer self-update
    echo ---------------------------------------------------------------
) else (
    echo ---------------------------------------------------------------
    echo COMPOSER IS NOT INSTALLED
    echo ---------------------------------------------------------------
)

set baseWamp=
set defaultPHPver=
set composerInstalled=
set phpFolder=

기본 버전의 PHP를 사용하려면이 명령 파일을 다음과 같이 호출하십시오.

> phppath

또는 이와 같은 특정 버전의 PHP를 얻으려면

> phppath 5.6.30