[perl] Perl의 백틱, 시스템 및 exec의 차이점은 무엇입니까?

일반적으로 내가 사용에서 system, open, IPC::Open2, 또는 IPC::Open3내가 원하는 무엇에 따라 달라집니다. qx//운영자는 간단하지만, 너무 빠른 해킹의 매우 유용한 외부로 그 기능에 제약되어있다. 내가 찾을 수 open많은보다 간편한합니다.

system: 명령을 실행하고 명령이 리턴 될 때까지 기다립니다.

사용은 system당신이 명령을 실행 할 때, 출력에 대한 상관 없어, 그리고 펄 스크립트 명령이 완료 될 때까지 아무것도하고 싶지 않아요.

#doesn't spawn a shell, arguments are passed as they are
system("command", "arg1", "arg2", "arg3");

또는

#spawns a shell, arguments are interpreted by the shell, use only if you
#want the shell to do globbing (e.g. *.txt) for you or you want to redirect
#output
system("command arg1 arg2 arg3");

qx//또는“ : 명령을 실행하고 STDOUT을 캡처하십시오.

사용 qx//당신이 STDOUT에 기록 무엇을 캡처 명령을 실행하려면, 그리고 펄 스크립트 명령이 완료 될 때까지 아무것도하고 싶지 않아요.

#arguments are always processed by the shell

#in list context it returns the output as a list of lines
my @lines = qx/command arg1 arg2 arg3/;

#in scalar context it returns the output as one string
my $output = qx/command arg1 arg2 arg3/;

exec: 현재 프로세스를 다른 프로세스로 바꿉니다.

명령을 실행하고 출력에 신경 쓰지 말고 명령이 돌아 오기를 기다리지 않을 때 exec함께 사용하십시오 fork. system정말 그냥

sub my_system {
    die "could not fork\n" unless defined(my $pid = fork);
    return waitpid $pid, 0 if $pid; #parent waits for child
    exec @_; #replace child with new process
}

또한 읽을 수 있습니다 waitpid및 perlipc설명서를.

open: 프로세스를 실행하고 STDIN 또는 STDERR에 파이프를 작성하십시오.

open프로세스의 STDIN에 데이터를 쓰거나 프로세스의 STDOUT에서 데이터를 읽으려고 할 때 사용하십시오 (동시에 둘다는 아님).

#read from a gzip file as if it were a normal file
open my $read_fh, "-|", "gzip", "-d", $filename
    or die "could not open $filename: $!";

#write to a gzip compressed file as if were a normal file
open my $write_fh, "|-", "gzip", $filename
    or die "could not open $filename: $!";

IPC :: Open2 : 프로세스를 실행하고 STDIN 및 STDOUT에 대한 파이프를 작성하십시오.

IPC::Open2프로세스의 STDIN 및 STDOUT에서 읽고 쓸 필요가있을 때 사용하십시오 .

use IPC::Open2;

open2 my $out, my $in, "/usr/bin/bc"
    or die "could not run bc";

print $in "5+6\n";

my $answer = <$out>;

IPC :: Open3 : 프로세스를 실행하고 STDIN, STDOUT 및 STDERR에 파이프를 작성하십시오.

IPC::Open3프로세스의 세 가지 표준 파일 핸들을 모두 캡처해야 할 때 사용 하십시오. 예제를 작성하지만 IPC :: Open2와 거의 같은 방식으로 작동하지만 인수와 세 번째 파일 핸들의 순서가 약간 다릅니다.

답변

use IPC::Open2;
my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'some', 'cmd', 'and', 'args');
waitpid( $pid, 0 );
my $child_exit_status = $? >> 8;

exec -> exec "command"; ,
system -> system("command"); and
backticks -> print `command`;

#!/usr/bin/perl
print "Need to start exec command";
my $data2 = exec('ls');
print "Now END exec command";
print "Hello $data2\n\n";

#!/usr/bin/perl
print "Need to start system command";
my $data2 = system('ls');
print "Now END system command";
print "Hello $data2\n\n";

#!/usr/bin/perl
print "Need to start backticks command";
my $data2 = `ls`;
print "Now END system command";
print "Hello $data2\n\n";