Perl

나는 약간 반 경쟁적이기로 결정하고 Perl에서 이러한 문제를 일반적으로 코딩하는 방법을 보여줍니다.
_{끝에 46 자 (총) 자 코드 골프 항목도 있습니다.}

이 처음 세 가지 예는 모두이 헤더로 시작합니다.

#! /usr/bin/env perl
use Modern::Perl;
# which is the same as these three lines:
# use 5.10.0;
# use strict;
# use warnings;

while( <> ){
  chomp;
  last unless $_;
  Collatz( $_ );
}

• 단순 재귀 버전

  use Sub::Call::Recur;
  sub Collatz{
    my( $n ) = @_;
    $n += 0; # ensure that it is numeric
    die 'invalid value' unless $n > 0;
    die 'Integer values only' unless $n == int $n;
    say $n;
    given( $n ){
      when( 1 ){}
      when( $_ % 2 != 0 ){ # odd
        recur( 3 * $n + 1 );
      }
      default{ # even
        recur( $n / 2 );
      }
    }
  }
  

• 단순 반복 버전

  sub Collatz{
    my( $n ) = @_;
    $n += 0; # ensure that it is numeric
    die 'invalid value' unless $n > 0;
    die 'Integer values only' unless $n == int $n;
    say $n;
    while( $n > 1 ){
      if( $n % 2 ){ # odd
        $n = 3 * $n + 1;
      } else { #even
        $n = $n / 2;
      }
      say $n;
    }
  }
  

• 최적화 된 반복 버전

  sub Collatz{
    my( $n ) = @_;
    $n += 0; # ensure that it is numeric
    die 'invalid value' unless $n > 0;
    die 'Integer values only' unless $n == int $n;
    #
    state @next;
    $next[1] //= 0; # sets $next[1] to 0 if it is undefined
    #
    # fill out @next until we get to a value we've already worked on
    until( defined $next[$n] ){
      say $n;
      #
      if( $n % 2 ){ # odd
        $next[$n] = 3 * $n + 1;
      } else { # even
        $next[$n] = $n / 2;
      }
      #
      $n = $next[$n];
    }
    say $n;
    # finish running until we get to 1
    say $n while $n = $next[$n];
  }
  

---

이제 v5.10.0 이전 버전의 Perl로 마지막 예제를 수행하는 방법을 보여 드리겠습니다.

#! /usr/bin/env perl
use strict;
use warnings;

while( <> ){
  chomp;
  last unless $_;
  Collatz( $_ );
}
{
  my @next = (0,0); # essentially the same as a state variable
  sub Collatz{
    my( $n ) = @_;
    $n += 0; # ensure that it is numeric
    die 'invalid value' unless $n > 0;

    # fill out @next until we get to a value we've already worked on
    until( $n == 1 or defined $next[$n] ){
      print $n, "\n";

      if( $n % 2 ){ # odd
        $next[$n] = 3 * $n + 1;
      } else { # even
        $next[$n] = $n / 2;
      }
      $n = $next[$n];
    }
    print $n, "\n";

    # finish running until we get to 1
    print $n, "\n" while $n = $next[$n];
  }
}

---

기준

먼저 IO는 항상 느린 부분이 될 것입니다. 따라서 실제로 그대로 벤치마킹했다면 각각의 속도가 거의 같아야합니다.

그런 다음이를 테스트하기 위해 /dev/null( $null)에 대한 파일 핸들을 열고 say $n대신 읽기 위해 every 를 편집했습니다 say {$null} $n. 이것은 IO에 대한 의존성을 줄이기위한 것입니다.

#! /usr/bin/env perl
use Modern::Perl;
use autodie;

open our $null, '>', '/dev/null';

use Benchmark qw':all';

cmpthese( -10,
{
  Recursive => sub{ Collatz_r( 31 ) },
  Iterative => sub{ Collatz_i( 31 ) },
  Optimized => sub{ Collatz_o( 31 ) },
});

sub Collatz_r{
  ...
  say {$null} $n;
  ...
}
sub Collatz_i{
  ...
  say {$null} $n;
  ...
}
sub Collatz_o{
  ...
  say {$null} $n;
  ...
}

10 번 실행 한 후 다음은 대표적인 샘플 출력입니다.

            재귀 반복 최적화 평가
재귀 1715 / s--27 % -46 %
반복 2336 / s 36 %--27 %
최적화 됨 3187 / s 86 % 36 %-

---

마지막으로 실제 코드 골프 항목 :

perl -nlE'say;say$_=$_%2?3*$_+1:$_/2while$_>1'

총 46 자

시작 값을 인쇄 할 필요가없는 경우 5자를 더 제거 할 수 있습니다.

perl -nE'say$_=$_%2?3*$_+1:$_/2while$_>1'

_{실제 코드 부분은} 41 자 총
_{31 자이지만 -n스위치 없이는 코드가 작동하지 않습니다 . 그래서 나는 전체 예를 내 계산에 포함시킵니다.}