Inno Setup을 사용하여 설치 프로그램을 만들고 있습니다.
설치 프로그램이 이전에 설치된 버전을 덮어 쓰지 않고 자동으로 제거하도록하고 싶습니다. 어떻게 할 수 있습니까?
답변
AppId (즉 AppID,- [Setup]섹션 에서 사용한 값)가 주어지면 레지스트리에서 제거 문자열을 읽을 수 있어야합니다 . 사용 된 실제 값으로 대체해야하는 위치에서 찾을 수 있습니다 Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\( HKLM또는 HKCU일 수 있으므로 둘 다 선택하는 것이 가장 좋습니다) {AppId}. 를 찾아 UninstallString나 QuietUninstallString값과 사용 Exec하여에서 실행하는 기능을 InitializeSetup()이벤트 기능.
업데이트 : 이 문제를 지적한 모든 댓글 작성자 덕분에- [Run]섹션 항목을 사용하여 작동하지 않는 대체 솔루션을 제거 {uninstallexe}했습니다!
답변
나는 다음을 사용했습니다. 가장 간단한 방법인지는 모르겠지만 효과가 있습니다.
이것은 {#emit SetupSetting("AppId")}Inno Setup Preprocessor에 의존하는 사용 입니다. 사용하지 않는 경우 앱 ID를 직접 잘라내어 붙여 넣으십시오.
[Code]
{ ///////////////////////////////////////////////////////////////////// }
function GetUninstallString(): String;
var
sUnInstPath: String;
sUnInstallString: String;
begin
sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
sUnInstallString := '';
if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
Result := sUnInstallString;
end;
{ ///////////////////////////////////////////////////////////////////// }
function IsUpgrade(): Boolean;
begin
Result := (GetUninstallString() <> '');
end;
{ ///////////////////////////////////////////////////////////////////// }
function UnInstallOldVersion(): Integer;
var
sUnInstallString: String;
iResultCode: Integer;
begin
{ Return Values: }
{ 1 - uninstall string is empty }
{ 2 - error executing the UnInstallString }
{ 3 - successfully executed the UnInstallString }
{ default return value }
Result := 0;
{ get the uninstall string of the old app }
sUnInstallString := GetUninstallString();
if sUnInstallString <> '' then begin
sUnInstallString := RemoveQuotes(sUnInstallString);
if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
Result := 3
else
Result := 2;
end else
Result := 1;
end;
{ ///////////////////////////////////////////////////////////////////// }
procedure CurStepChanged(CurStep: TSetupStep);
begin
if (CurStep=ssInstall) then
begin
if (IsUpgrade()) then
begin
UnInstallOldVersion();
end;
end;
end;
대안
한 단계 더 나아가 이전에 설치된 버전의 버전 번호를 읽고 현재 설치 패키지의 버전 번호와 비교하는 이 블로그 게시물 “Inno Setup Script Sample for Version Comparison” 을 참조하십시오 .
답변
“이전 아이콘을 제거하려면”(당신의 아이콘이 변경 / 업데이트 되었기 때문에) 다음을 사용할 수 있습니다.
; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;
이것은 “설치를 시작할 때”실행되므로 기본적으로 이전 아이콘을 제거하고이 작업이 완전히 완료된 후에도 새 아이콘이 계속 설치됩니다.
나는 “무엇이든 변경된 경우”아이콘을 현명하게 설치할 때마다이 작업을 수행합니다 (어쨌든 모두 다시 설치됩니다).
답변
Inno Setup을 사용할 때 다른 설치 프로그램에서 해당 버전을 설치하지 않는 한 이전 버전을 제거 할 이유가 없습니다. 그렇지 않으면 업그레이드가 자동으로 처리됩니다.
답변
Craig McQueen이 제공 한 대답은 완전히 실행 가능합니다. 그러나 나는 그 주석을 추가 할 것이다.
{#emit SetupSetting("AppId")}난 그냥 내 앱 ID를 추가 할 수 있도록 코드는 나를 위해 작동하지 않습니다.- 제거 프로그램에 의해 제거 된 AppData / 폴더에 INI 구성 파일이 저장되어 있고 새 버전을 설치할 때 지워지는 것을 원하지 않기 때문에 제거 프로그램을 실행하고 싶지 않았습니다. 그래서 나는 경로를 검색 한 후 프로그램이 설치된 디렉토리를 제거하기 위해 Craig McQueen이 제공 한 코드를 약간 수정했습니다.
따라서 Craig McQueen의 코드와 관련하여 변경 사항은 다음과 같습니다.
InstallLocation키 대신 키를 검색하십시오UninstallString.DelTree대신 함수를 사용하십시오.Exec(sUnInstallString, ...)
답변
GetUninstallString()위에서 제안한 방법 을 사용하여 내부 제거를 강제 CurStepChanged()하고 디스크 캐싱 문제가있는 사용자는 제거 프로그램 exe가 삭제 될 때까지 제거 후 실제로 잠시 대기하는 관련 솔루션을 아래에서 참조하십시오!
답변
[code] 섹션에서 제거 프로그램을 실행할 수 있습니다. 기존 제거 프로그램의 경로를 얻는 방법을 알아야합니다. 간단하게 앱을 설치할 때 제거 프로그램이 포함 된 폴더를 가리키는 레지스트리 문자열 값을 추가하고 InitializeWizard 콜백에서 제거 프로그램을 실행합니다.
Inno 설치 제거 프로그램 이름은 모두 uninsnnn.exe 형식이므로 코드에서이를 고려해야합니다.
