[excel] Microsoft Excel ActiveX 컨트롤이 비활성화 되었습니까?

저는 Excel 개발자이며이 일이 발생했을 때 분명히 고통을 느꼈습니다. 다행히 Excel이 실행 중일 때도 VBA에서 MSForms.exd 파일의 이름을 변경하여 문제를 해결할 수있는 해결 방법을 찾을 수있었습니다. 스프레드 시트를 배포해야하는 Excel 개발자는 MS 업데이트에 영향을받지 않도록 스프레드 시트에 다음 VBA 코드를 추가 할 수 있습니다.

이 코드를 임의의 모듈에 배치하십시오.

Public Sub RenameMSFormsFiles()
  Const tempFileName As String = "MSForms - Copy.exd"
  Const msFormsFileName As String = "MSForms.exd"
  On Error Resume Next

  'Try to rename the C:\Users\[user.name]\AppData\Local\Temp\Excel8.0\MSForms.exd file  
  RenameFile Environ("TEMP") & "\Excel8.0\" & msFormsFileName, Environ("TEMP") & "\Excel8.0\" & tempFileName
  'Try to rename the C:\Users\[user.name]\AppData\Local\Temp\VBE\MSForms.exd file  
  RenameFile Environ("TEMP") & "\VBE\" & msFormsFileName, Environ("TEMP") & "\VBE\" & tempFileName
End Sub

Private Sub RenameFile(fromFilePath As String, toFilePath As String)
  If CheckFileExist(fromFilePath) Then
      DeleteFile toFilePath
      Name fromFilePath As toFilePath
  End If
End Sub

Private Function CheckFileExist(path As String) As Boolean
  CheckFileExist = (Dir(path) <> "")
End Function

Private Sub DeleteFile(path As String)
  If CheckFileExist(path) Then
      SetAttr path, vbNormal
      Kill path
  End If
End Sub    

RenameMSFormsFiles 서브 루틴은 C:\Users\[user.name]\AppData\Local\Temp\Excel8.0\및 에서 MSForms.exd 파일의 이름을 바꾸려고합니다.C:\Users\[user.name]\AppData\Local\Temp\VBE\ 폴더 을 MSForms-Copy.exd로 바꾸려고합니다.

그런 다음 Workbook_Open 이벤트의 맨 처음에 RenameMSFormsFiles 서브 루틴을 호출합니다.

Private Sub Workbook_Open()
  RenameMSFormsFiles
End Sub

스프레드 시트가 열리면 MSForms.exd 파일의 이름을 바꾸려고합니다. 분명히 이것은 완벽한 해결책이 아닙니다.

1. 영향을받는 사용자는 스프레드 시트를 처음 열 때 VBA 코드를 실행할 때 여전히 ActiveX 컨트롤 오류가 발생합니다. VBA 코드를 한 번 실행하고 Excel을 다시 시작한 후에 만 ​​문제가 해결됩니다. 일반적으로 사용자가 손상된 스프레드 시트를 발견 할 때 매우 빠른 반응은 Excel을 닫고 스프레드 시트를 다시 열려는 것입니다. 🙂
2. MSForms.exd 파일은 MSForms.exd 파일에 문제가없는 경우에도 스프레드 시트를 열 때마다 이름이 변경됩니다. 그러나 스프레드 시트는 잘 작동합니다.

최소한 지금은 Excel 개발자가 Microsoft에서 수정 사항을 릴리스 할 때까지이 해결 방법으로 작업을 계속 배포 할 수 있습니다.

이 솔루션을 여기에 게시했습니다 .

답변