[cmake] CMake에서 GLOB 또는 각 파일을 사용하여 소스 파일을 개별적으로 지정하는 것이 더 좋습니까?

의존성을 유지하기 위해 추가 파일을 희생하여 안전하게 구할 수 있습니다.

다음과 같은 기능을 어딘가에 추가하십시오.

# Compare the new contents with the existing file, if it exists and is the
# same we don't want to trigger a make by changing its timestamp.
function(update_file path content)
    set(old_content "")
    if(EXISTS "${path}")
        file(READ "${path}" old_content)
    endif()
    if(NOT old_content STREQUAL content)
        file(WRITE "${path}" "${content}")
    endif()
endfunction(update_file)

# Creates a file called CMakeDeps.cmake next to your CMakeLists.txt with
# the list of dependencies in it - this file should be treated as part of
# CMakeLists.txt (source controlled, etc.).
function(update_deps_file deps)
    set(deps_file "CMakeDeps.cmake")
    # Normalize the list so it's the same on every machine
    list(REMOVE_DUPLICATES deps)
    foreach(dep IN LISTS deps)
        file(RELATIVE_PATH rel_dep ${CMAKE_CURRENT_SOURCE_DIR} ${dep})
        list(APPEND rel_deps ${rel_dep})
    endforeach(dep)
    list(SORT rel_deps)
    # Update the deps file
    set(content "# generated by make process\nset(sources ${rel_deps})\n")
    update_file(${deps_file} "${content}")
    # Include the file so it's tracked as a generation dependency we don't
    # need the content.
    include(${deps_file})
endfunction(update_deps_file)

그런 다음 globbing로 이동하십시오.

file(GLOB_RECURSE sources LIST_DIRECTORIES false *.h *.cpp)
update_deps_file("${sources}")
add_executable(test ${sources})

이전과 같이 명시 적 종속성을 계속 사용하고 모든 자동화 된 빌드를 트리거하고 있습니다. 하나가 아닌 두 개의 파일 만 있습니다.

새 파일을 만든 후에 만 ​​절차가 변경됩니다. glob을 사용하지 않으면 워크 플로는 Visual Studio 내부에서 CMakeLists.txt를 수정하고 다시 작성하는 것입니다. glob을 수행하는 경우 cmake를 명시 적으로 실행하거나 CMakeLists.txt를 터치하면됩니다.

답변