[apple] iPhone 연락처를 생성하는 스크립트

Applescript는 OS X 주소록 항목을 대량 생성 한 다음 iPhone으로 가져올 수 있습니다. 나는 당신을 위해 기본적인 것을 만들었습니다.

-- Change these to your desired data
set firstName to "Test"
set lastName to "User"
set numberOfEntries to "5" as integer

set counter to "1" as integer
tell application "Address Book"
    repeat numberOfEntries times
        set thePerson to make new person with properties {first name:firstName, last name:lastName & " " & counter}
        make new email at end of emails of thePerson with properties {label:"Work", value:"test" & counter & "@example.com"}
        make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
        set counter to counter + 1
    end repeat
    save
end tell

폴더 에서 AppleScript 편집기를 열고 Applications/Utilities/새 스크립트에 붙여 넣습니다. 그대로 5 개의 연락처를 다음과 같이 만듭니다.

set numberOfEntries to "5" as integer줄 의 숫자를 필요한만큼 변경할 수 있으며 원하는 경우 데이터를 변경할 수 있습니다. 전화 번호와 같은 다른 입력란이 필요한 경우 문의하여 방법을 알려 드리겠습니다.

개선 된 버전

나는 약간 배 밖으로 가서 더 좋은 이름을 가진 버전을 만들었습니다. 나는 가장 인기있는 20 명의 남성과 여성의 이름, 40 개의 가장 인기있는 성을 취하고 중간 이니셜을 추가 했으므로 중복 가능성이 거의 없습니다 (2000의 경우 5 % 미만, 내 수학에 의해). 구피 찾고 번호가 매겨진 연락처.

또한 모든 연락처를 그룹 ( “테스트 그룹”)에 추가하므로 기존 주소록에 추가하고 나중에 정리하려는 경우 모든 더미 연락처를 쉽게 선택할 수 있습니다.

편집 : 나는 또한 얼마나 많은 항목을 만들 것인지 묻는 메시지를 표시하도록 변경 했으므로 코드를 편집 할 필요가 없습니다.

-- name lists: 20 most popular (US) male and female first names, 40 most popular last names
set firstNameList to {"Mary", "Patricia", "Linda", "Barbara", "Elizabeth", "Jennifer", "Maria", "Susan", "Margaret", "Dorothy", "Lisa", "Nancy", "Karen", "Betty", "Helen", "Sandra", "Donna", "Carol", "Ruth", "Sharon", "James", "John", "Robert", "Michael", "William", "David", "Richard", "Charles", "Joseph", "Thomas", "Christopher", "Daniel", "Paul", "Mark", "Donald", "George", "Kenneth", "Steven", "Edward", "Brian"}
set lastNameList to {"Smith", "Johnson", "Williams", "Jones", "Brown", "Davis", "Miller", "Wilson", "Moore", "Taylor", "Anderson", "Thomas", "Jackson", "White", "Harris", "Martin", "Thompson", "Garcia", "Martinez", "Robinson", "Clark", "Rodriguez", "Lewis", "Lee", "Walker", "Hall", "Allen", "Young", "Hernandez", "King", "Wright", "Lopez", "Hill", "Scott", "Green", "Adams", "Baker", "Gonzalez", "Nelson", "Carter"}
set initialList to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set counter to "1" as integer

-- prompt for how many contacts to create
set dialogText to "Number of contacts to create?"
repeat
    display dialog dialogText default answer ""
    set numberOfEntries to text returned of result
    try
        if numberOfEntries = "" then error
        set numberOfEntries to numberOfEntries as number
        exit repeat
    on error

    end try
end repeat

-- populate the address book
tell application "Address Book"
    set theGroup to make new group with properties {name:"Test Group"}
    repeat numberOfEntries times
        set firstName to some item of firstNameList
        set lastName to some item of lastNameList
        set middleInitial to some item of initialList & "."
        set thePerson to make new person with properties {first name:firstName, middle name:middleInitial, last name:lastName}
        make new email at end of emails of thePerson with properties {label:"Work", value:firstName & middleInitial & lastName & "@example.com"}
        make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
        add thePerson to theGroup
        set counter to counter + 1
    end repeat
    save
end tell

생성되는 내용은 다음과 같습니다.

답변