[resources] Mathematica 도구 가방에 무엇입니까? [닫은]

빈 노트를 열지 않고 시작

나는 Mathematica가 빈 노트북을 열어 놓고 시작하는 데 어려움을 겪었습니다. 이 노트북을 스크립트로 닫을 수는 있지만 여전히 잠깐 동안 깜박입니다. 내 해킹은 다음을 Invisible.nb포함 하는 파일을 만드는 것 입니다.

Notebook[{},Visible->False]

그리고 이것을 내 것에 추가하십시오 Kernel\init.m:

If[Length[Notebooks["Invisible*"]] > 0,
  NotebookClose[Notebooks["Invisible*"][[1]]]
]

SetOptions[$FrontEnd,
  Options[$FrontEnd, NotebooksMenu] /.
    HoldPattern["Invisible.nb" -> {__}] :> Sequence[]
]

이제 Mathematica를 열어서 시작합니다 Invisible.nb

더 좋은 방법이있을 수 있지만 이것이 나에게 도움이되었습니다.

---

사용자 정의 Fold및FoldList

Fold[f, x] 에 해당 Fold[f, First@x, Rest@x]

덧붙여서, 이것이 향후 버전의 Mathematica로 들어갈 수 있다고 생각합니다.

놀라다! 현재 문서화되어 있지는 않지만 구현되었습니다. Oliver Ruebenkoenig에 의해 2011 년에 구현되었다는 소식을 들었습니다. Oliver Ruebenkoenig에게 감사합니다!

Unprotect[Fold, FoldList]

Fold[f_, h_[a_, b__]] := Fold[f, Unevaluated @ a, h @ b]
FoldList[f_, h_[a_, b__]] := FoldList[f, Unevaluated @ a, h @ b]

(* Faysal's recommendation to modify SyntaxInformation *)
SyntaxInformation[Fold]     = {"ArgumentsPattern" -> {_, _, _.}};
SyntaxInformation[FoldList] = {"ArgumentsPattern" -> {_, _., {__}}};

Protect[Fold, FoldList]

이것을 허용하도록 업데이트되었습니다.

SetAttributes[f, HoldAll]
Fold[f, Hold[1 + 1, 2/2, 3^3]]

f[f[1 + 1, 2/2], 3^3]

---

“동적 파티션”

Mathematica.SE 포스트 # 7512 참조이 기능의 새 버전은 를 .

종종 일련의 길이에 따라 목록을 분할하려고합니다.

의사 코드 예 :

partition[{1,2,3,4,5,6}, {2,3,1}]

산출: {{1,2}, {3,4,5}, {6}}

나는 이것을 생각해 냈다.

dynP[l_, p_] :=
 MapThread[l[[# ;; #2]] &, {{0} ~Join~ Most@# + 1, #} &@Accumulate@p]

인수 테스트를 포함하여 이것으로 완료했습니다.

dynamicPartition[l_List, p : {_Integer?NonNegative ..}] :=
  dynP[l, p] /; Length@l >= Tr@p

dynamicPartition[l_List, p : {_Integer?NonNegative ..}, All] :=
  dynP[l, p] ~Append~ Drop[l, Tr@p] /; Length@l >= Tr@p

dynamicPartition[l_List, p : {_Integer?NonNegative ..}, n__ | {n__}] :=
  dynP[l, p] ~Join~ Partition[l ~Drop~ Tr@p, n] /; Length@l >= Tr@p

세 번째 인수는 스플릿 사양 이외의 요소에 발생하는 사항을 제어합니다.

---

Szabolcs의 Mathematica 트릭

가장 자주 사용하는 것은 Paste Tabular Data Palette입니다.

CreatePalette@
 Column@{Button["TSV",
    Module[{data, strip},
     data = NotebookGet[ClipboardNotebook[]][[1, 1, 1]];
     strip[s_String] :=
      StringReplace[s, RegularExpression["^\\s*(.*?)\\s*$"] -> "$1"];
     strip[e_] := e;
     If[Head[data] === String,
      NotebookWrite[InputNotebook[],
       ToBoxes@Map[strip, ImportString[data, "TSV"], {2}]]]]],
   Button["CSV",
    Module[{data, strip},
     data = NotebookGet[ClipboardNotebook[]][[1, 1, 1]];
     strip[s_String] :=
      StringReplace[s, RegularExpression["^\\s*(.*?)\\s*$"] -> "$1"];
     strip[e_] := e;
     If[Head[data] === String,
      NotebookWrite[InputNotebook[],
       ToBoxes@Map[strip, ImportString[data, "CSV"], {2}]]]]],
   Button["Table",
    Module[{data}, data = NotebookGet[ClipboardNotebook[]][[1, 1, 1]];
     If[Head[data] === String,
      NotebookWrite[InputNotebook[],
       ToBoxes@ImportString[data, "Table"]]]]]}

---

내부에서 외부 데이터 수정 Compile

최근 Daniel Lichtblau는 내가 본 적이없는이 방법을 보여주었습니다. 내 의견으로는 그것은 유틸리티를 크게 확장시킵니다.Compile

ll = {2., 3., 4.};
c = Compile[{{x}, {y}}, ll[[1]] = x; y];

c[4.5, 5.6]

ll

(* Out[1] = 5.6  *)

(* Out[2] = {4.5, 3., 4.}  *)

---