[unit-testing] GTest 및 CMake 작업을 시작하는 방법

나는 최근에 C ++ 프로젝트를 컴파일하기 위해 CMake를 사용하여 판매되었으며 이제 내 코드에 대한 일부 단위 테스트 작성을 시작하고 싶습니다. 이 문제를 해결하기 위해 Google 테스트 유틸리티를 사용하기로 결정했지만 시작하는 데 도움이 필요합니다.

저는 하루 종일 다양한 가이드와 예제를 읽고 있었는데 여기에는 Primer , IBM 소개 , SO에 대한 몇 가지 질문 ( 여기 및 여기 ) 및 제가 놓친 다른 소스가 포함됩니다. 나는 거기에 많은 것이 있다는 것을 알고 있지만 어떻게 든 여전히 어려움을 겪고 있습니다.

현재 gtest를 컴파일 / 설치했고 작동하지 않는지 확인하기 위해 가장 기본적인 테스트를 구현하려고합니다. 유일한 소스 파일 (testgtest.cpp)은 이 이전의 대답 :

#include <iostream>

#include "gtest/gtest.h"

TEST(sample_test_case, sample_test)
{
    EXPECT_EQ(1, 1);
}

내 관련 CMakeLists.txt는 다음과 같습니다.

cmake_minimum_required(VERSION 2.6)
project(basic_test)

# Setup testing
enable_testing()
find_package(GTest REQUIRED)
include_directories(${GTEST_INCLUDE_DIR})

# Add test cpp file
add_executable(runUnitTests
    testgtest.cpp
)

# Link test executable against gtest & gtest_main
target_link_libraries(runUnitTests ${GTEST_LIBRARY_DEBUG} ${GTEST_MAIN_LIBRARY_DEBUG})

add_test(
    NAME runUnitTests
    COMMAND runUnitTests
)

cpp 파일의 끝에 main을 제공하는 대신 gtest_main에 링크하기로 선택했습니다. 이렇게하면 여러 파일로 테스트를보다 쉽게 ​​확장 할 수 있습니다.

생성 된 .sln 파일 (Visual C ++ 2010 Express에서)을 빌드 할 때 불행히도 양식의 긴 오류 목록이 표시됩니다.

2>msvcprtd.lib(MSVCP100D.dll) : error LNK2005: "public: virtual __thiscall std::basic_iostream<char,struct std::char_traits<char> >::~basic_iostream<char,struct std::char_traits<char> >(void)" (??1?$basic_iostream@DU?$char_traits@D@std@@@std@@UAE@XZ) already defined in gtestd.lib(gtest-all.obj)

이것은 gtest 라이브러리에 성공적으로 연결되지 않았다는 것을 의미합니다. 디버그 라이브러리에 연결할 때 디버그 모드에서 빌드를 시도했는지 확인했습니다.

편집하다

좀 더 파고 들었을 때 내 문제는 내가 gtest를 구축하고있는 라이브러리 유형과 관련이 있다고 생각합니다. CMake로 gtest를 빌드 할 때BUILD_SHARED_LIBS 체크되지 않은 프로그램을 이러한 .lib 파일에 연결하면 위에서 언급 한 오류가 발생합니다. 그러나이 BUILD_SHARED_LIBS체크 되면 .lib 및 .dll 파일 세트를 생성합니다. 이제 이러한 .lib 파일에 연결하면 프로그램이 컴파일되지만 실행시 gtest.dll을 찾을 수 없다고 불평합니다.

a SHARED와 not SHARED라이브러리 의 차이점은 무엇이며 공유하지 않도록 선택하면 왜 작동하지 않습니까? 내 프로젝트에 대한 CMakeLists.txt에 누락 된 옵션이 있습니까?

답변

cmake_minimum_required(VERSION 2.6)
project(basic_test)

################################
# GTest
################################
ADD_SUBDIRECTORY (gtest-1.6.0)
enable_testing()
include_directories(${gtest_SOURCE_DIR}/include ${gtest_SOURCE_DIR})

################################
# Unit Tests
################################
# Add test cpp file
add_executable( runUnitTests testgtest.cpp )
# Link test executable against gtest & gtest_main
target_link_libraries(runUnitTests gtest gtest_main)
add_test( runUnitTests runUnitTests )

cmake_minimum_required (VERSION 3.1)

project (registerer)

##################################
# Download and install GoogleTest

include(ExternalProject)
ExternalProject_Add(gtest
  URL https://googletest.googlecode.com/files/gtest-1.7.0.zip
  # Comment above line, and uncomment line below to use subversion.
  # SVN_REPOSITORY http://googletest.googlecode.com/svn/trunk/
  # Uncomment line below to freeze a revision (here the one for 1.7.0)
  # SVN_REVISION -r700

  PREFIX ${CMAKE_CURRENT_BINARY_DIR}/gtest
  INSTALL_COMMAND ""
)
ExternalProject_Get_Property(gtest source_dir binary_dir)

################
# Define a test
add_executable(registerer_test registerer_test.cc)

######################################
# Configure the test to use GoogleTest
#
# If used often, could be made a macro.

add_dependencies(registerer_test gtest)
include_directories(${source_dir}/include)
target_link_libraries(registerer_test ${binary_dir}/libgtest.a)
target_link_libraries(registerer_test ${binary_dir}/libgtest_main.a)

##################################
# Just make the test runnable with
#   $ make test

enable_testing()
add_test(NAME    registerer_test
         COMMAND registerer_test)

cmake_minimum_required(VERSION 3.15)
project(sample CXX)
enable_testing()
find_package(GTest REQUIRED)
add_executable(test1 test.cpp source.cpp)
target_link_libraries(test1 GTest::GTest GTest::Main)
add_test(test-1 test1)

SET(CMAKE_EXE_LINKER_FLAGS /NODEFAULTLIB:\"msvcprtd.lib;MSVCRTD.lib\")

FOREACH(flag_var
    CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
    CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
    if(${flag_var} MATCHES "/MD")
        string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
    endif(${flag_var} MATCHES "/MD")
ENDFOREACH(flag_var)