[excel] MS Excel 버전 관리를 수행하는 가장 좋은 방법

@Demosthenex의 답변을 한 단계 더 발전 시키면 Microsoft Excel Objects 및 UserForms의 코드를 추적하려면 약간 까다로워 야합니다.

먼저 SaveCodeModules()내보내려는 다른 유형의 코드를 설명하기 위해 기능을 변경했습니다 .

Sub SaveCodeModules(dir As String)

'This code Exports all VBA modules
Dim moduleName As String
Dim vbaType As Integer

With ThisWorkbook.VBProject
    For i = 1 To .VBComponents.count
        If .VBComponents(i).CodeModule.CountOfLines > 0 Then
            moduleName = .VBComponents(i).CodeModule.Name
            vbaType = .VBComponents(i).Type

            If vbaType = 1 Then
                .VBComponents(i).Export dir & moduleName & ".vba"
            ElseIf vbaType = 3 Then
                .VBComponents(i).Export dir & moduleName & ".frm"
            ElseIf vbaType = 100 Then
                .VBComponents(i).Export dir & moduleName & ".cls"
            End If

        End If
    Next i
End With

End Sub

VBA 코드와 마찬가지로 UserForms를 내보내고 가져올 수 있습니다. 유일한 차이점은 양식을 내보낼 때 두 개의 파일이 생성된다는 것입니다 ( 각 UserForm에 .frm대한 .frx파일 과 파일이 제공됨). 이 중 하나는 작성한 소프트웨어를 보유하고 다른 하나는 양식의 레이아웃을 정의하는 바이너리 파일입니다.

마이크로 소프트 엑셀 (MEOs)는 (의미 개체 Sheet1, Sheet2, ThisWorkbook등)을로 내보낼 수 있습니다 .cls파일. 그러나이 코드를 통합 문서로 다시 가져 오려면 VBA 모듈과 같은 방식으로 가져 오려고하면 해당 시트가 통합 문서에 이미 있으면 오류가 발생합니다.

이 문제를 해결하기 위해 .cls 파일을 Excel로 가져 오려고하지 않고 .cls파일을 Excel로 대신 문자열로 읽은 다음이 문자열을 빈 MEO에 붙여 넣습니다. 내 ImportCodeModules는 다음과 같습니다.

Sub ImportCodeModules(dir As String)

Dim modList(0 To 0) As String
Dim vbaType As Integer

' delete all forms, modules, and code in MEOs
With ThisWorkbook.VBProject
    For Each comp In .VBComponents

        moduleName = comp.CodeModule.Name

        vbaType = .VBComponents(moduleName).Type

        If moduleName <> "DevTools" Then
            If vbaType = 1 Or _
                vbaType = 3 Then

                .VBComponents.Remove .VBComponents(moduleName)

            ElseIf vbaType = 100 Then

                ' we can't simply delete these objects, so instead we empty them
                .VBComponents(moduleName).CodeModule.DeleteLines 1, .VBComponents(moduleName).CodeModule.CountOfLines

            End If
        End If
    Next comp
End With

' make a list of files in the target directory
Set FSO = CreateObject("Scripting.FileSystemObject")
Set dirContents = FSO.getfolder(dir) ' figure out what is in the directory we're importing

' import modules, forms, and MEO code back into workbook
With ThisWorkbook.VBProject
    For Each moduleName In dirContents.Files

        ' I don't want to import the module this script is in
        If moduleName.Name <> "DevTools.vba" Then

            ' if the current code is a module or form
            If Right(moduleName.Name, 4) = ".vba" Or _
                Right(moduleName.Name, 4) = ".frm" Then

                ' just import it normally
                .VBComponents.Import dir & moduleName.Name

            ' if the current code is a microsoft excel object
            ElseIf Right(moduleName.Name, 4) = ".cls" Then
                Dim count As Integer
                Dim fullmoduleString As String
                Open moduleName.Path For Input As #1

                count = 0              ' count which line we're on
                fullmoduleString = ""  ' build the string we want to put into the MEO
                Do Until EOF(1)        ' loop through all the lines in the file

                    Line Input #1, moduleString  ' the current line is moduleString
                    If count > 8 Then            ' skip the junk at the top of the file

                        ' append the current line `to the string we'll insert into the MEO
                        fullmoduleString = fullmoduleString & moduleString & vbNewLine

                    End If
                    count = count + 1
                Loop

                ' insert the lines into the MEO
                .VBComponents(Replace(moduleName.Name, ".cls", "")).CodeModule.InsertLines .VBComponents(Replace(moduleName.Name, ".cls", "")).CodeModule.CountOfLines + 1, fullmoduleString

                Close #1

            End If
        End If

    Next moduleName
End With

End Sub

이 dir두 함수 에 대한 입력으로 인해 혼동되는 경우 코드 리포지토리입니다! 따라서 다음과 같이 이러한 함수를 호출합니다.

SaveCodeModules "C:\...\YourDirectory\Project\source\"
ImportCodeModules "C:\...\YourDirectory\Project\source\"